mIRC Girişte Şehir Gösterme ve Şehir Yasaklama

Aytac

Developer
Yönetici
Developer
Katılım
4 Şub 2020
Mesajlar
373
Tepkime puanı
17
Puanları
18
Konum
ircland
Web sitesi
www.ircalem.net
mIRC Şehir yasaklama addonu
Kod:
on *:text:*:#Opers:{
  if $regex($1,/^[!.-]yasak/Si) {
    if !$2 { msg # Lütfen !yasak <ekle|sil|list> olarak belirtiniz. }
    elseif $regex($2,/^ekle$/Si) {
      if !$3 { msg # Lütfen !yasak <ekle> <Şehir> olarak belirtiniz. }
      elseif $regex($3,/Bel[ıiİ]rs[ıiİ]z/Si) { msg # Böyle bir şehir yok :) }
      elseif $hget(YasakS,$strip($3)) { msg # $strip($3) şehri yasak listesinde zaten ekli, neyin kafası. }
      else { .hadd -ms YasakS $strip($3) $nick | .hsave -o YasakS yasaks.tprk | msg # $strip($3) şehri yasak listesine eklendi. }
    }
    elseif $regex($2,/^s[ıiİ]l$/Si) {
      if !$3 { msg # Lütfen !yasak <sil> <Şehir> olarak belirtiniz. }
      elseif !$hget(YasakS,$strip($3)) { msg # $strip($3) şehri yasak listesinde ekli değil. }
      else { .hdel -ms YasakS $strip($3) | .hsave -o YasakS yasaks.tprk | msg # $strip($3) şehri yasak listesinden silindi. }
    }
    elseif $regex($2,/^l[ıiİ]st$/Si) {
      if !$hget(YasakS,0).data { msg # Yasak şehir listesi boş. }
      else {
        msg # Yasak şehir listesi
        msg # -
        var %:t = 1 | while %:t <= $hget(YasakS,0).data {
          msg # $+(%:t,.,$chr(41)) Şehir:4 $hget(YasakS,%:t).item  Ekleyen:2 $hget(YasakS,%:t).data
          inc %:t
        }
        msg # -
        msg # Yasak şehir listesi sonu
      }
    }
  }
}
on *:start:if $isfile(yasaks.tprk) { .hmake YasakS | .hload YasakS yasaks.tprk }
on *:snotice:*:if $regex($1-,/Client connecting (on port|at) .+\: (.+) \([email protected]+\)/Si) { who +I $regml(2) }
raw 352:*:{ var %:r $r(1000,99999) | sockopen $+(isp,%:r) www.ipaddresslocation.org 80 | sockmark $+(isp,%:r) $+($4,¿,$6) }
on *:sockopen:isp*:{
  if ($sockerr) { .sockclose $sockname | return }
  sockwrite -nt $sockname GET $+(/ip-address-locator.php?lookup=,$token($sock($sockname).mark,1,191)) HTTP/1.1
  sockwrite -nt $sockname Host: $sock($sockname).addr
  sockwrite -nt $sockname Connection: keep-alive
  sockwrite -nt $sockname Accept: text/html,application/xhtml+xml,application/xml;q=0.9,image/webp,*/*;q=0.8
  sockwrite -nt $sockname User-Agent: Mozilla/5.0 (Windows NT 6.1) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/40.0.2214.111 Safari/537.36
  sockwrite -nt $sockname $crlf
}
on *:sockread:isp*:{
  var %:isp | sockread -f %:isp | tokenize 32 %:isp
  if $regex($1-,/IP Country:<\/i> <b>(.+)<\/b>/i) { .hadd -ms Ülke $sockname $iif($regml(1),$regml(1),Belirsiz) }
  elseif $regex($1-,/IP City: <b>(.+)<\/b>/i) {
    .hadd -ms Sehir $sockname $iif($regml(1),$regml(1),Belirsiz)
    if $hget(YasakS,$regml(1)) { .gzline $+(*@,$token($sock($sockname).mark,1,191)) +5h Yasak şehir girişi.. }
  }
  elseif $regex($1-,/ISP Provider:<\/i> <b>(.+)<\/b>/i) {
    $iif(!$window(@Network),window -e @Network)
    echo -t @Network [ GİRİŞ ] Nick:4 $token($sock($sockname).mark,2,191) - IP:4 $token($sock($sockname).mark,1,191) - Ülke:2 $hget(Ülke,$sockname) - Şehir:2 $hget(Sehir,$sockname) - ISP:5 $iif($regml(1),$regml(1),Belirsiz) $iif($hget(YasakS,$hget(Sehir,$sockname)),- 4Yasak Şehir Girişi!)
    .hdel -ms Ülke $sockname | .hdel -ms Sehir $sockname
    sockclose $sockname
  }
}

#Opers kanalında;
  • !yasak ekle Şehir
  • !yasak sil Şehir
  • !yasal list

Gibi kullanabilirsiniz..

Kendin kullanacaksan eğer;
Kod:
on *:text:*:#Opers:{

Böyle değiştir;
Kod:
on *:input:#Opers:{
 
Üst